In this chapter we start a new Seaside application that will incorporate more of the complexities normally found in a sophisticated web application. The primary focus of this chapter is how to incorporate CSS (for layout and style) and images in your web application.

Imagine that your child has been recruited to play on the best youth football (*soccer* for you Americans) team in the region, *Los Boquit*as.[[1]](#footnote-1) All the parents are expected to be involved and instead of coaching on the field, you have agreed to create a web site to manage some team information. After a review of various technologies, you have decided to use Seaside.

Following is a screen shot of the basic structure, showing various pieces of a web site (header, sidebar, main, image, footer), that we will build.



This layout is, of course, completely arbitrary. Web page layout is best done by a designer and that designer should provide sample HTML and the CSS to go with the HTML. As a programmer, your job is to translate the HTML into Smalltalk code and reference the supplied CSS.

1. First we will define a home page for the site. We will use 'LB' (for *Los Boquitas*) as the prefix for our classes. While some Smalltalk dialects (Cincom and GemStone) support namespaces, this is a convention that helps avoid name conflict when porting code across dialects. Launch Pharo and enter the following class definition:

WAComponent subclass: #LBMain

instanceVariableNames: ''

classVariableNames: ''

category: 'LosBoquitas'

* 1. Previously we have registered our application by evaluating an expression in a workspace. As the expression gets more complex, it becomes desirable to put the expression in a method and then just call it from a workspace. This allows us to manage the code with our source code management tools (tracking versions, etc.). An added benefit is that when a class is first loaded using the code management tools, the message ‘initialize’ is sent to the class. This means that our application can be automatically registered when it is loaded into a new Smalltalk object space.

Click on the ‘Class’ radio button in the center bar to specify that we are adding a *class-side* method. In this method we register the name (boquitas) and also specify that we want to use a WASession as the session class. This is the default and it expires a session that is inactive for a configurable period (the default is 10 minutes).

initialize

"

LBMain initialize.

"

(WAAdmin register: self asApplicationAt: 'boquitas')

preferenceAt: #sessionClass put: WASession;

yourself.

* 1. Now we are ready to add some content. Add this *instance*-side method to LBMain (select the "inst. side" radio button to switch back to the instance side):

renderContentOn: html

html heading

level: 1;

with: 'Los Boquitas Soccer Team'.

1. Now initialize your component by executing the following in a workspace:

LBMain initialize.

Alternatively, you can switch back to the class side, select the initialize method, click anywhere on the third line, and press <Ctrl>+<D>. Don’t forget to switch back to the instance side!

1. Finally, start at the dispatcher page, <http://localhost:8080/browse>, and follow the link to boquitas. If your application is not visible, then go back and see if you put the proper methods on the class side of LBMain. If they are on the instance side, then things will not work.
2. Now we will start the process of adding an image.
   1. Modify the render method in LBMain so that there is an image tag but it points to a file that does not exist:

renderContentOn: html

html heading

level: 1;

with: 'Los Boquitas Soccer Team'.

**html image**

**url: 'boquitas.jpg';**

**yourself.**

* 1. Try viewing the page and notice that the image does not display. Depending on your browser, a placeholder might be displayed. At a minimum we need some alternate text to be displayed when the image is missing. Modify the render method again:

renderContentOn: html

html heading

level: 1;

with: 'Los Boquitas Soccer Team'.

html image

**altText: 'children playing soccer';**

url: '/images/boquitas.jpg';

yourself.

* 1. Try viewing the page and see if the alternate text is displayed. In Safari the text is not displayed, but this is a feature, not a bug! Technically, the official definition of the alt attribute is that it is for user agents (browsers) that are unable to display images (such as screen readers for visually impaired users). Since Safari can display images, the alt attribute may be ignored.
  2. Now we could update the link to reference a site that does have the picture. (If you are not connected to the Internet, skip to step #5.) Modify the render method to point to an external server with the file. (If you are running a local server, you can download the file and install it in your local images directory.)

renderContentOn: html

html heading

level: 1;

with: 'Los Boquitas Soccer Team'.

html image

altText: 'children playing soccer';

**url: 'https://github.com/jgfoster/SeasideTutorial/' ,**

**'blob/master/boquitas.jpg?raw=true';**

yourself.

* 1. View the page and verify that the image shows.

1. While having an external server provide static data (such as images) is efficient (reducing the load on your local server—in our case the Pharo VM), it does mean that your application is not completely self-contained. Sometimes for development, testing, or demos it is nice to have even static data served from Smalltalk (and as long as you can’t measure the performance impact, why not?). To support serving static data, Seaside provides an abstract class, WAFileLibrary.
   1. Save a copy of the image to a local directory. You can do this from your web browser by right-clicking on the image and selecting ‘Save image as…’ (the exact menu command will differ based on your web browser). Alternatively, get the file from the Git checkout.
   2. Create a subclass of WAFileLibrary to handle static data for our application (click in the :

WAFileLibrary subclass: #LBFileLibrary

instanceVariableNames: ''

classVariableNames: ''

category: 'LosBoquitas'

* 1. Add the downloaded image to the file library by evaluating an expression in a workspace that includes the path to the file (this will, of course, differ based on your machine).

LBFileLibrary addFileAt: 'C:\temp\boquitas.jpg'

* 1. Now using the System Browser, note that a new method (‘boquitasJpg’) has been added to the instance side of LBFileLibrary. Modify the render method to reference the new library. Notice how the class LBFileLibrary understands the ‘/’ message and returns a reference to the static file.

renderContentOn: html

html heading

level: 1;

with: 'Los Boquitas Soccer Team'.

html image

altText: 'children playing soccer';

**url: LBFileLibrary / 'boquitas.jpg';**

yourself.

* 1. If you view source in your web browser, you can see that Seaside generated the following element for the page:

<img alt="children playing soccer" src="/files/LBFileLibrary/boquitas.jpg">

1. Adding a page title.
2. Note that the page is simply titled "Seaside" rather than something more descriptive. Add the following instance-side method to LBMain:

updateRoot: anHtmlRoot

super updateRoot: anHtmlRoot.

anHtmlRoot title: 'Los Boquitas'.

1. View the page again and note that it now has a title.
2. Creating multiple areas.
3. The typical web site has a header, a side-bar, a main content area, and a footer. We will now add these pieces by modifying the render method again. Note that the #’with:’ message is the last one sent to each element since this causes the HTML tag to be written and closed.

renderContentOn: html

html div

id: 'allcontent';

with: [

html div

id: 'header';

class: 'section';

with: [

html heading

level1;

with: 'Los Boquitas Soccer Team'.

].

html div

id: 'main';

class: 'section';

with: [

html image

altText: 'children playing soccer';

url: LBFileLibrary / 'boquitas.jpg';

yourself.

].

html div

id: 'sidebar';

class: 'section';

with: [

html heading

level2;

with: 'Sidebar'.

].

html div

id: 'footer';

class: 'section';

with: [

html text: 'Copyright (c) ' , Date today year printString.

].

].

1. View the page and confirm that the various pieces exist. Note, however, that they do not have any formatting.
2. Until recently, the typical way of doing page layout was to use a table. This approach is no longer recommended and the better approach is to use Cascading Style Sheets (CSS). In chapter 5 we saw that a ‘style’ method on our component could provide style. This is useful for simple experiments, but Seaside provides alternatives.
   1. Add the following method to the instance side of LBFileLibrary (not LBMain!):

boquitasCss

^'body {

font-family: Georgia, "Times New Roman", Times, serif;

font-size: small;

}

#allcontent {

width: 770px;

padding-top: 5px;

padding-bottom: 5px;

background-color: #fff0d0;

margin-left: auto;

margin-right: auto;

}

\*.section {

background-color: #ffeabf;

}

#header {

margin: 10px;

}

#main {

padding: 15px;

margin: 0px 10px 10px 10px;

width: 550px;

float: right;

}

#sidebar {

padding: 15px;

margin: 0px 600px 10px 10px;

}

#footer {

color: #204670;

text-align: center;

padding: 15px;

margin: 10px;

clear: right;

}'

* 1. Modify the root component to reference the style sheet (back to LBMain!):

updateRoot: anHtmlRoot

super updateRoot: anHtmlRoot.

anHtmlRoot title: 'Los Boquitas'.

**anHtmlRoot link**

**type: 'text/css';**

**beStylesheet;**

**addAll;**

**url: LBFileLibrary / 'boquitas.css';**

**yourself.**

1. Let's refactor the render code so that it is more modular.
   1. Add the following four methods:

renderHeaderOn: html

html div

id: 'header';

class: 'section';

with: [

html heading

level1;

with: 'Los Boquitas Soccer Team';

yourself.

];

yourself.

renderMainOn: html

html div

id: 'main';

class: 'section';

with: [

html image

altText: 'children playing soccer';

url: LBFileLibrary / 'boquitas.jpg';

yourself.

];

yourself.

renderSidebarOn: html

html div

id: 'sidebar';

class: 'section';

with: [

html heading

level2;

with: 'Sidebar';

yourself.

];

yourself.

renderFooterOn: html

html div

id: 'footer';

class: 'section';

with: [

html text: 'Copyright (c) ' , Date today year printString.

];

yourself.

* 1. And now modify the renderContentOn: method to call these new methods:

renderContentOn: html

html div

id: 'allcontent';

with: [

self

renderHeaderOn: html;

renderMainOn: html;

renderSidebarOn: html;

renderFooterOn: html;

yourself.

].

* 1. View the application in a web browser to confirm that it displays the page shown at the beginning of this chapter.

1. Save your Pharo image.

1. The first version of this tutorial was in 2007 and was held in Buenos Aires, the home of *Club Atlético Boca Juniors*. *Boca* is Spanish for ‘river mouth’ and the club is in a neighborhood on the mouth of the Matanza River. The idea of naming a children’s team ‘Little Mouths’ seemed appropriate. [↑](#footnote-ref-1)